problem

題目描述
農夫約翰想要建造一個圍欄用來圍住他的奶牛，可是他資金匱乏。他建造的圍欄必須包括他的奶牛喜歡吃草的所有地點。對於給出的這些地點的座標，計算最短的能夠圍住這些點的圍欄的長度。

PROGRAM NAME: fc

INPUT FORMAT

輸入資料的第一行包括一個整數 N。N（0 <= N <= 10,000）表示農夫約翰想要圍住的放牧點的數目。接下來 N 行，每行由兩個實陣列成，Xi 和 Yi,對應平面上的放牧點座標（-1,000,000 <= Xi,Yi <= 1,000,000）。數字用小數表示。

SAMPLE INPUT (file fc.in)

4

4 8

4 12

5 9.3

7 8

OUTPUT FORMAT

輸出必須包括一個實數，表示必須的圍欄的長度。答案保留兩位小數。

SAMPLE OUTPUT (file fc.out)

12.00
輸入
輸出
樣例輸入
樣例輸出
資料範圍限制

analysis

由於本人心血來潮我重新寫了另一篇排版更好看更好懂的凸包blog

好，看完了嗎？理解了嗎？
所以，這道題完全就是一道凸包裸題
我們用graham把凸包上的點全部求出，再計算凸包中兩兩相鄰的點的距離和就可以了

code

新學的OIers建議別直接看程式碼，還是儘量手擼，自己理解理解

type
        point=record
 

                x,y:extended;
        end;
var
        f:array[0..10000]of point;
        angle:array[0..10000]of
        record
                x,y,value,dis:extended;
        end;//x，y座標，value角度，dis與原點距離
        stack:array[0..10000]of longint;
        row,rank:extended;
        n,i,j,tot,up:longint;
        ans:extended;
function
 
 judge(ax,ay,bx,by,cx,cy:extended):extended;
begin//判斷點是否在直線左側
        exit(ax*by+cx*ay+bx*cy-cx*by-bx*ay-ax*cy);
end;
function arccot(xx,yy:extended):extended;
begin//返回一個點連原點與x軸正半軸的夾角
        if yy=0 then exit(0);
        if xx=0 then exit(90);
        arccot:=arctan(yy/xx)*180/pi;//計算幾何，這裡用pascal自帶的三角函式arctan
        if xx<0 then arccot:=arccot+180;
end;
procedure qsort(l,r:longint);
var//快排，不解釋
        i,j:longint;
        mid,mid1:extended;
begin
        i:=l;
        j:=r;
        mid:=angle[(l+r)shr 1].value;
        mid1:=angle[(l+r)shr 1].dis;
        repeat
                while (angle[i].value<mid)or(angle[i].value=mid)and(angle[i].dis<mid1)do inc(i);
                while (angle[j].value>mid)or(angle[j].value=mid)and(angle[j].dis>mid1)do dec(j);
                if i<=j then
                begin
                        angle[0]:=angle[i];
                        angle[i]:=angle[j];
                        angle[j]:=angle[0];
                        inc(i);
                        dec(j);
                end;
        until i>j;
        if l<j then qsort(l,j);
        if i<r then qsort(i,r);
end;
begin
        readln(n);
        rank:=maxlongint;

        for i:=1 to n do
        with f[i] do
        begin
                readln(x,y);
                if y<rank then
                begin
                        row:=x;
                        rank:=y;
                end;//記錄最底下的點的行列值
        end;
        for i:=1 to n do
        with f[i] do
        begin
                x:=x-row;
                y:=y-rank;
        end;//把所有點平移一下，使沒有點會在三四象限內
        tot:=1;
        for i:=1 to n do
        with f[i] do
        if (x<>0)or(y<>0) then
        begin
                inc(tot);
                angle[tot].value:=arccot(x,y);
                angle[tot].x:=x;
                angle[tot].y:=y;
                angle[tot].dis:=sqrt(x*x+y*y);
        end;
        qsort(2,n);//按角度為第一關鍵字、距離為第二關鍵字排序
        up:=2;
        stack[1]:=1;
        stack[2]:=2;
        for i:=3 to n do
        begin
                while judge(angle[stack[up-1]].x,angle[stack[up-1]].y,angle[stack[up]].x,angle[stack[up]].y,angle[i].x,angle[i].y)<0 do dec(up);//判斷當前點是否滿足要求
                inc(up);
                stack[up]:=i;//入棧
        end;
        ans:=0;
        stack[up+1]:=stack[1];
        for i:=1 to up do
        ans:=ans+sqrt(sqr(angle[stack[i]].x-angle[stack[i+1]].x)+sqr(angle[stack[i]].y-angle[stack[i+1]].y));
        writeln(ans:0:2);//統計凸包上兩兩相鄰的點的距離，輸出
end.