1、靜態SQL語句效能優於動態SQL語句，如果功能確定最好使用靜態SQL語句

2、使用execute immediate語句，用於處理除了多行查詢之外的任何動態SQL，包括DDL、DCL、DML、以及單行Select語句

3、使用動態引用遊標OPEN-FOR、FETCH、CLOSE語句處理多行查詢語句

4、使用批量的動態SQL語句，可以提高pl/sql效能

一、處理DDL語句

begin
  declare
    v_sql varchar2(2000);
  begin
    v_sql:='create table test as select * from dept';
    execute immediate v_sql;
  end;
end;
 

二、處理DCL語句

begin
  declare
    v_sql varchar2(2000);
  begin
    v_sql:='grant select on test to user_01';
    execute immediate v_sql;
  end;
end;

三、處理DML語句

根據DML語句是否有佔位符、是否是returning子句處理方式不同

1、處理無佔位符和returning子句的DML語句

begin
  declare
    v_sql varchar2(2000);
  begin
    v_sql:='update test set loc=''HELLOWORLD'' where deptno=10';
    execute immediate v_sql;
  end;
end;
 

2、處理有佔位符無returning子句的DML語句

begin
  declare
    v_sql varchar2(2000);
  begin
    v_sql:='update test set loc=:loc where deptno=:deptno';
    execute immediate v_sql using &1,&2;
  end;
end;

3、處理無佔位符有returning子句的DML語句

begin
  declare
    v_sql varchar2(2000);
    v_dname dept.dname%type;
  begin
    v_sql:='update test set loc=''HELLOWORLD'' where deptno=10 returning dname into :name';
    execute immediate v_sql returning into v_dname;
    dbms_output.put_line(v_dname||'被更新');      
  end;
end;
 

4、處理含佔位符有returning子句的DML語句

begin
  declare
    v_sql varchar2(2000);
    v_dname dept.dname%type;
  begin
    v_sql:='update test set loc=''HELLOWORLD'' where deptno=:deptno returning dname into :name';
    execute immediate  v_sql using &deptno returning into v_dname;
    dbms_output.put_line(v_dname||'被更新');      
  end;
end;

四、處理單行查詢

begin
  declare
    v_sql varchar2(2000);
    v_record dept%rowtype;
  begin
    v_sql:='select * from dept where deptno=:deptno';
    execute immediate v_sql into v_record using &deptno ;
    dbms_output.put_line('部門名稱：'||v_record.dname);      
  end;
end;

通過記錄變數來獲取資料

五、處理多行查詢

begin
  declare
    type dept_cur is ref cursor;
    c_dept dept_cur;
    v_sql varchar2(2000);
    v_record dept%rowtype;
  begin
    v_sql:='select * from dept where deptno=:deptno';
    open c_dept for v_sql using &deptno;
    loop
      fetch c_dept into v_record;
      exit when c_dept%NOTFOUND;
      dbms_output.put_line('部門名稱：'||v_record.dname);      
    end loop;
    close c_dept;    
  end;
end;

六、在動態SQL語句中使用批量繫結

在動態SQL語句中使用批量繫結，可以加快批量資料的處理速度，提高效能；

當使用批量繫結時，集合元素要使用SQL的資料型別而非PL/SQL資料型別，最好通過%TYPE,%ROWTYPE來

（1）、在動態DML語句上面使用批量繫結

語法：

FORALL index IN 1..v_tab.count
     execute immediate v_sql using v_tab(i);

舉例：

begin
  declare
    type dept_var is varray(3) of dept.deptno%type;
    v_dept dept_var;
    v_sql varchar2(2000);    
  begin
    v_dept:=dept_var(1,2,3);
    v_sql:='update dept set loc=''測試資料'' where deptno=:deptno';    
    forall i IN 1..v_dept.count
      execute immediate v_sql using v_dept(i) ;    
  end;
end;

（2）、在DML返回子句上使用批量繫結

語法：

execute immediate v_sql
   returning bulk collect into v_coll;

舉例：

begin
  declare
    type dname_tab is table of dept.dname%type;
    v_name dname_tab;
    type loc_tab is table of dept.loc%type;
    v_loc loc_tab;
    v_sql varchar2(2000);    
  begin    
    v_sql:='update dept set loc=''測試資料DDDDD'' where deptno=:deptno returning dname,loc into :1,:2';       
    execute immediate v_sql using &deptno returning bulk collect into v_name,v_loc;    
    for i IN 1..v_name.count loop
      dbms_output.put_line('部門名稱：'||v_name(i)||'  地址：'||v_loc(i));      
    end loop;
  end;
end;

（3）、在execute immediate語句上使用批量繫結查詢語句

語法：

execute immediate v_sql bulk collect into v_coll;

舉例：

begin
  declare
    type dname_tab is table of dept.dname%type;
    v_name dname_tab;
    type loc_tab is table of dept.loc%type;
    v_loc loc_tab;
    v_sql varchar2(2000);    
  begin    
    v_sql:='select dname,loc from dept where deptno=:deptno';       
    execute immediate v_sql bulk collect into v_name,v_loc using &deptno;    
    for i IN 1..v_name.count loop
      dbms_output.put_line('部門名稱：'||v_name(i)||'  地址：'||v_loc(i));      
    end loop;
  end;
end;

（4）、在遊標FETCH語句中使用批量提取

語法：

fetch v_cursor bulk collect into v_coll;

舉例：

begin
  declare
    type c_ref is ref cursor;
    c_dept c_ref;
    type dname_tab is table of dept.dname%type;
    v_name dname_tab;
    type loc_tab is table of dept.loc%type;
    v_loc loc_tab;
    v_sql varchar2(2000);    
  begin    
    v_sql:='select dname,loc from dept where deptno=:deptno';  
    open c_dept for v_sql using &deptno;
    fetch c_dept bulk collect into v_name,v_loc;
    close c_dept;
    
    for i IN 1..v_name.count loop
      dbms_output.put_line('部門名稱：'||v_name(i)||'  地址：'||v_loc(i));      
    end loop;    
  end;
end;